# This example describes an example use case of Federated Properties
# being used in conjunction with a Federated Query.
#
# In this example we are setting up a local wikibase repository for publications where
# we have created a few items and assigned them the statement of P577 (Publication date).
# With this setup we querying the local database and the federated source wiki for 
# any written work (Q47461344) with a publication date after 2000-01-01.
#
# Uncomment row 31 to narrow down the search for a specific genre

#defaultView:Timeline
PREFIX wd-wdt: <http://www.wikidata.org/prop/direct/>
PREFIX wd-wd: <http://www.wikidata.org/entity/>

SELECT ?item ?itemLabel ?pubDate ?image
WHERE
{
  {
    SELECT ?item ?itemLabel ?pubDate 
    WHERE
    {
      ?item wdt:P577 ?pubDate .
      OPTIONAL { ?item wd:P18 ?image }
    }
  }
  UNION
  {
   SERVICE <https://query.wikidata.org/sparql> {
     ?item wd-wdt:P577 ?pubDate .
     ?item wd-wdt:P31 wd-wd:Q47461344 .
     #?item wd-wdt:P136 wd-wd:Q8261 . # genre novel (Q8261)
     OPTIONAL { ?item wd-wdt:P18 ?image }
   } 
  }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "en". }
  FILTER (?pubDate > "2000-01-01T00:00:00+00:00"^^xsd:dateTime)
}
ORDER BY DESC(?pubDate)
LIMIT 100

# This example describes an example use case of Federated Properties
# being used in conjunction with a Federated Query.
#
# In this example we have setup a local wikibase repository and created an 
# item with the federated property International Standard Name Identifier (P213)
#
# Running this query we are asking the local instance and the federated source wiki
# to return all items that are identified by INSI "0000 0001 1364 8293" which on
# wikidata.org returns Berlin and on your local instance could be just about anything.

PREFIX wd-wdt: <http://www.wikidata.org/prop/direct/>

SELECT ?item ?ISNI
WHERE
{
  VALUES ?ISNI {"0000 0001 1364 8293"}
  {
    SELECT ?item ?ISNI 
    WHERE
    {
        ?item wdt:P213 ?ISNI;
    }
  }
  UNION
  {
   SERVICE <https://query.wikidata.org/sparql> {
        ?item wd-wdt:P213 ?ISNI;
   } 
  }
}