Data Challenge - SPARQL - Wikidata
Μεσολόγγι & 200 χρόνια από την Έξοδο (1826–2026)

Για βοήθεια μπορείτε να δείτε και το παλαιότερο data challenge με τις απαντήσεις του.
Ionian Wikithon - Data Challenge 2022

1. Για "ζέσταμα": Βρείτε τα Wikidata items:

Αναζητήστε τα ακόλουθα items στο wikidata.org: Μεσολόγγι (πόλη), Έξοδος του Μεσολογγίου, Πολιορκία του Μεσολογγίου, Ελληνική Επανάσταση του 1821, Αιτωλοακαρνανία, Λόρδοσ Βύρωνας.
Χρήσιμες ιδιότητες: instance of (P31) · part of (P361) · located in (P131) · coordinate location (P625) · place of death (P20) · place of birth (P19)

Missolonghi (Q642810)
Exodus of Messolonghi (Q12872505)
Third Siege of Missolonghi (Q650567)
Second Siege of Missolonghi (Q4127950)
First Siege of Missolonghi (Q3394840)
Greek War of Independence (Q182062)
Lord Byron (Q5679)
Aetolia-Acarnania Regional Unit (Q202624)

2. Βρείτε τον δήμο και την περιφέρεια στην οποία ανήκει το Μεσολόγγι.

3. Εμφανίστε στο χάρτη το Μεσολόγγι με τις συντεταγμένες του.

4. Βρείτε όλες τις πολιορκίες του Μεσολογγίου με τις ημερομηνίες τους.

4b. Εμφανίστε τις σε μία χρονοσειρά (timeline).

5. Βρείτε όλα τα πρόσωπα που πέθαναν στο Μεσολόγγι με την ημερομηνία θανάτου τους.

6. Δημιουργήστε λίστα ατόμων που γεννήθηκαν στο Μεσολόγγι, ταξινομημένη κατά ημερομηνία γέννησης.

7. Εμφανίστε σε timeline όλες τις μάχες και πολιορκίες που αποτελούν μέρος της Ελληνικής Επανάστασης.

8. Απεικονίστε στο χάρτη τις μάχες και πολιορκίες της Ελληνικής Επανάστασης που έχουν καταγεγραμμένες συντεταγμένες.

9. Δημιουργήστε image grid με εικόνες προσώπων που σχετίζονται με την Ελληνική Επανάσταση.

10. Βρείτε πρόσωπα που συμμετείχαν στην Έξοδο του Μεσολογγίου ή στην Πολιορκία.

11. Βρείτε όλα τα πρόσωπα που χαρακτηρίζονται ως φιλέλληνες (philhellene) στο Wikidata.

Δοκιμάστε με P135 (movement) και επίσης με P106 (occupation) Philhellenism (Q695274)

12. Εμφανίστε σε bubble chart τους ανθρώπους που συμμετείχαν στην Ελληνική Επανάσταση με βάση τη χώρα προέλευσής τους.

13. Βρείτε έργα τέχνης που έχουν ως κύριο θέμα (main subject) το Μεσολόγγι ή την Έξοδο του Μεσολογγίου ή απεικονίζουν (depicts) σκηνές από εκεί.

και ενδεικτικός κώδικας:

Data Challenge - SPARQL - Wikidata
Μεσολόγγι & 200 χρόνια από την Έξοδο (1826–2026)

1. Για "ζέσταμα": Βρείτε τα Wikidata items:

Αναζητήστε τα ακόλουθα items στο wikidata.org: Μεσολόγγι (πόλη), Έξοδος του Μεσολογγίου, Πολιορκία του Μεσολογγίου, Ελληνική Επανάσταση του 1821, Αιτωλοακαρνανία, Λόρδοσ Βύρωνας.
Χρήσιμες ιδιότητες: instance of (P31) · part of (P361) · located in (P131) · coordinate location (P625) · place of death (P20) · place of birth (P19)

Missolonghi (Q642810)
Exodus of Messolonghi (Q12872505)
Third Siege of Missolonghi (Q650567)
Second Siege of Missolonghi (Q4127950)
First Siege of Missolonghi (Q3394840)
Greek War of Independence (Q182062)
Lord Byron (Q5679)
Aetolia-Acarnania Regional Unit (Q202624)

2. Βρείτε τον δήμο και την περιφέρεια στην οποία ανήκει το Μεσολόγγι.

SELECT ?city ?cityLabel ?municipality ?municipalityLabel ?region ?regionLabel
WHERE {

BIND(wd:Q642810 AS ?city)
OPTIONAL { ?city wdt:P131 ?municipality. }
OPTIONAL { ?city wdt:P131/wdt:P131 ?region. }
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}

3. Εμφανίστε στο χάρτη το Μεσολόγγι με τις συντεταγμένες του.

SELECT ?city ?cityLabel ?municipality ?municipalityLabel ?region ?regionLabel
WHERE {

BIND(wd:Q642810 AS ?city)
OPTIONAL { ?city wdt:P131 ?municipality. }
OPTIONAL { ?city wdt:P131/wdt:P131 ?region. }
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}

4. Βρείτε όλες τις πολιορκίες του Μεσολογγίου με τις ημερομηνίες τους.

4b. Εμφανίστε τις σε μία χρονοσειρά (timeline).

#defaultView:Timeline
SELECT ?siege ?siegeLabel ?siegeDescription ?start ?end
WHERE {

?siege wdt:P31/wdt:P279* wd:Q188055.  # instance of siege
?siege wdt:P276/wdt:P131* wd:Q642810. # located at Missolonghi
OPTIONAL { ?siege wdt:P580 ?start. }
OPTIONAL { ?siege wdt:P582 ?end. }
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}
ORDER BY ?start

5. Βρείτε όλα τα πρόσωπα που πέθαναν στο Μεσολόγγι με την ημερομηνία θανάτου τους.

SELECT ?person ?personLabel ?personDescription ?deathDate
WHERE {

?person wdt:P31 wd:Q5;              # instance of human
        wdt:P20/wdt:P131* wd:Q642810. # died in Missolonghi
OPTIONAL { ?person wdt:P570 ?deathDate. }
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}
ORDER BY ?deathDate

6. Δημιουργήστε λίστα ατόμων που γεννήθηκαν στο Μεσολόγγι, ταξινομημένη κατά ημερομηνία γέννησης.

SELECT ?person ?personLabel ?personDescription ?birthDate
WHERE {

?person wdt:P31 wd:Q5;              # instance of human
        wdt:P19/wdt:P131* wd:Q642810. # born in Missolonghi
OPTIONAL { ?person wdt:P569 ?birthDate. }
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}
ORDER BY ?birthDate

7. Εμφανίστε σε timeline όλες τις μάχες και πολιορκίες που αποτελούν μέρος της Ελληνικής Επανάστασης.

#defaultView:Timeline
SELECT ?event ?eventLabel ?start ?end
WHERE {

?event wdt:P361 wd:Q182062.          # part of Greek War of Independence
?event wdt:P31/wdt:P279* wd:Q178561. # instance of battle
OPTIONAL { ?event wdt:P580 ?start. }
OPTIONAL { ?event wdt:P582 ?end. }
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}
ORDER BY ?start

8. Απεικονίστε στο χάρτη τις μάχες και πολιορκίες της Ελληνικής Επανάστασης που έχουν καταγεγραμμένες συντεταγμένες.

#defaultView:Map
SELECT ?event ?eventLabel ?coords ?start
WHERE {

?event wdt:P361 wd:Q182062;           # part of Greek War of Independence
       wdt:P31/wdt:P279* wd:Q178561;  # instance of battle
       wdt:P625 ?coords.              # with coordinates
OPTIONAL { ?event wdt:P580 ?start. }
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}
ORDER BY ?start

9. Δημιουργήστε image grid με εικόνες προσώπων που σχετίζονται με την Ελληνική Επανάσταση.

#defaultView:ImageGrid
SELECT DISTINCT ?person ?personLabel ?image
WHERE {

?person wdt:P31 wd:Q5;
        wdt:P18 ?image.
{ ?person wdt:P20/wdt:P131* wd:Q642810. }   # died in Missolonghi
UNION
{ ?person wdt:P19/wdt:P131* wd:Q642810. }   # born in Missolonghi
UNION
{ ?person wdt:P607 wd:Q182062. }             # fought in the war
SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}

}

10. Βρείτε πρόσωπα που συμμετείχαν στην Έξοδο του Μεσολογγίου ή στην Πολιορκία.

SELECT DISTINCT ?person ?personLabel ?personDescription
WHERE {

SERVICE wikibase:label {
  bd:serviceParam wikibase:language "el,en".
}
{
  SELECT ?person WHERE {
    ?person wdt:P31 wd:Q5.
    {
      ?person wdt:P607 wd:Q650567.    # fought in Siege of Missolonghi
    }
    UNION
    {
      ?person wdt:P1344 wd:Q12872505.  # participant in Exodus
    }
  }
}

}
ORDER BY ?personLabel

11. Βρείτε όλα τα πρόσωπα που χαρακτηρίζονται ως φιλέλληνες (philhellene) στο Wikidata.

Δοκιμάστε με P135 (movement) και επίσης με P106 (occupation) Philhellenism (Q695274)

SELECT ?person ?personLabel ?personDescription ?nationality ?nationalityLabel
WHERE {

?person wdt:P31 wd:Q5;
        wdt:P135 wd:Q695274.   # movement = Philhellenism
OPTIONAL { ?person wdt:P27 ?nationality. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "el,en". }

}
ORDER BY ?nationalityLabel ?personLabel

SELECT ?person ?personLabel ?personDescription ?nationality ?nationalityLabel
WHERE {

?person wdt:P31 wd:Q5;
        wdt:P106 wd:Q695274.   # movement = Philhellenism
OPTIONAL { ?person wdt:P27 ?nationality. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "el,en". }

}
ORDER BY ?nationalityLabel ?personLabel

12. Εμφανίστε σε bubble chart τους ανθρώπους που συμμετείχαν στην Ελληνική Επανάσταση με βάση τη χώρα προέλευσής τους.

#defaultView:BubbleChart
SELECT ?nationality ?nationalityLabel (COUNT(?person) AS ?count)
WHERE {

?person wdt:P31 wd:Q5;
        wdt:P607 wd:Q182062;    # fought in Greek War of Independence          
        wdt:P27 ?nationality.
SERVICE wikibase:label { bd:serviceParam wikibase:language "el,en". }

}
GROUP BY ?nationality ?nationalityLabel
ORDER BY DESC(?count)

13. Βρείτε έργα τέχνης που έχουν ως κύριο θέμα (main subject) το Μεσολόγγι ή την Έξοδο του Μεσολογγίου ή απεικονίζουν (depicts) σκηνές από εκεί.

SELECT DISTINCT ?work ?workLabel ?workDescription ?creator ?creatorLabel ?date
WHERE {

{ ?work wdt:P921 wd:Q642810. }     # main subject = Missolonghi
UNION
{ ?work wdt:P180 wd:Q642810. }     # depicts Missolonghi
UNION
{ ?work wdt:P921 wd:Q12872505. }    # main subject = Exodus
UNION
{ ?work wdt:P180 wd:Q12872505. }    # depicts the Exodus
OPTIONAL { ?work wdt:P170 ?creator. }
OPTIONAL { ?work wdt:P571 ?date. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "el,en". }

}
ORDER BY ?date